MDaemon 9.6.2 Rus

[haviras.livejournal.com]

1. Куда мдемон ложит архивный файл конфигурации, который экспортирует из меню
Файл - заархивировать конфигурацию
2. Как его восстановить?
3. Будет ли конфигурашка от русского мдемона работать на английском? А то меня его глюки достали

Comments

[haviras.livejournal.com]

Спасибо.
Это не сложно, действительно, если бы не достаточно объемное количество юзерей.

Парсер, на похапе, сортировку напишу если совсем грустно будет.

В этом есть свой мазохизм: день писать парсер и день отлаживать, когда за 3 часа можно руками...

[pan-2.livejournal.com]

так. я не совсем пойму, где сложности? просто именно не пойму
вот пример мдаемоновской базы
(http://www.radikal.ru)
первый столбец прибиваем, столбец "Пассворд" перетаскиваем на второе место, столбец "domain" на третье, все остальные прибиваем,
прибиваем первую строчку, сохраняем как csv.
должно получится

abcd,password,domain.ru
...


берём скрипт (лень проверять отличается ли он от того что в форуме, мы его пользовали)

'script to add users to hMailServer
'found here http://hmailserver.com/forum/viewtopic.php?t=2634
'usage: import2hmail_from_csv.vbs import.csv
'import.csv format: User;username;password;domain.com
'or
'import.csv format: Alias;aliasname;forward_to;domain.com

Option Explicit

Dim obBaseApp
Dim objFSO
Dim objTextFile
Dim strNewAlias,i

Const ForReading = 1

Set obBaseApp = CreateObject("hMailServer.Application")
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile("import.csv", ForReading) 'Change the name of Objects.csv to the name of your CSV file that you put in the same directory as the script.

'CHANGE ADMIN PASSWORD HERE!!!!
Call obBaseApp.Authenticate ("Administrator", "Forever")

Do While objTextFile.AtEndOfStream <> True
strNewAlias = split(objTextFile.Readline, ";")

Select Case strNewAlias(0)
Case "User"
AddUser strNewAlias(1), strNewAlias(2), strNewAlias(3)
Case "Alias"
AddAlias strNewAlias(1), strNewAlias(2), strNewAlias(3)
End Select

i = i + 1
Loop

Sub AddAlias(strAlias,strEmailAddress,strDomain)
Dim obDomain
Dim obAliases
Dim obNewAlias

Set obDomain = obBaseApp.Domains.ItemByName(strDomain)
Set obAliases = obDomain.Aliases
Set obNewAlias = obAliases.Add()

obNewAlias.Name = strAlias & "@" & strDomain 'username
obNewAlias.Value = strEmailAddress 'password
obNewAlias.Active = 1 'activates user
obNewAlias.Save() 'saves account

Set obNewAlias = Nothing
Set obAliases = Nothing
Set obDomain = Nothing

End Sub

Sub AddUser(strUsername, strPassword, strDomain)
Dim obDomain
Dim obAccounts
Dim obNewAccount

Set obDomain = obBaseApp.Domains.ItemByName(strDomain)
Set obAccounts = obDomain.Accounts
Set obNewAccount = obAccounts.Add()

obNewAccount.Address = strUsername & "@" & strDomain 'username
obNewAccount.Password = strPassword 'password
obNewAccount.Active = 1 'activates user
obNewAccount.Maxsize = 0 'sets mailbox size, 0=unlimited
obNewAccount.Save() 'saves account

Set obNewAccount = Nothing
Set obDomain = Nothing
Set obAccounts = Nothing

End Sub

вуаля.
это про это сложности или я что-то не понял?

[haviras.livejournal.com]

О! Огромное спасибо. Скрипт на vba?

Сложностей нету. Единственное что меня смущает, это то, что если скрипты не пойдут, то руками придется все делать. Надеюсь пойдут

Огромное спасибо еще раз